Vamos a completar el desarrollo de las funciones especiales del Excel que son:
- Función Coincidir
- Función Indice

Función Coincidir

Sintaxis:
=Coincidir(DatoBuscado,RangoDondeSeBusca,TipoCoincidencia)
<

Devuelve la posición del "DatoBuscado" dentro de la lista (rango) "RangoDondeSeBusca".

> El "Tipo de coincidencia" puede ser: -1: Coincidencia por defecto; 1: Coincidencia por exceso; 0: Coincidencia exacta.
Si nosotros sabemos que el dato buscado está en el rango, usaremos 0 como tipo de coincidencia.

Función Indice

Sintaxis:
=Indice(RangoDeDondeSeExtrae,NroFila [,NroColumna])

Devuelve el elemento del RangoDondeSeBusca que se encuentra en la posición dada por NroFila. Si el rango es una matriz, se usa también NroColumna.

Abra el archivo "IndiceCoincidir.xlsx" haciendo clic aquí

En la primera hoja, tenemos alguna explicación adicional de estas dos funciones que, como veremos, es muy útil al usarlas conjuntamente.
Tenemos una pequeña tabla de las ventas de los meses de Enero a Diciembre.
En el lado derecho, varias preguntas que deben ser resueltas usando estas funciones.
Empecemos con la primera: ¿Cuál fue la máxima venta?
En I14 debemos ingresar: =Max(B4:B15)

¿Cuál es el número de mes, correspondiente a Julio?
Se trata de extraer la posición que ocupa "Julio" dentro del rango B4:B15 (Meses).
Puesto que la función Indice devuelve un valor y la función Coincidir devuelve una posición, debemos usar ésta última.
En I16 digitamos: =COINCIDIR("Julio",A4:A15,0)
En I18 debemos obtener el número de mes en el cual se produjo la máxima venta. Esto significa que debemos buscar la máxima venta en la columna B.
Esto lo haremos con la función coincidir, el número que devuelva será el mismo que ocupa el mes requerido.
Entonces, en I18 digitamos: =COINCIDIR(MAX(B4:B15),B4:B15,0).
Como se puede ver, extraemos la máxima venta y eso lo buscamos en Ventas.
En I20 se pide el monto de la venta; es decir, el valor de un elemento de la lista, no se pide la posición de un elemento.
Aquí es cuando usamos la función Indice. Esta necesita de dónde y qué número de elemento.
Significa que debemos buscar la posición o numero del elemento "Julio" en la lista de los meses, para que mediante Indice, extraigamos el elemento que ocupa esa posición en la columna de Ventas.
Luego en I20 digitamos: =INDICE(B4:B15,COINCIDIR("Julio",A4:A15,0))
Es decir, coincidir devuelve 7 y, del rango B4:B15 (Ventas), extraemos el sétimo elemento que es 5028.
Realizando el mismo análisis respondemos la siguiente pregunta.
En I22 digitamos: =INDICE(A4:A15,COINCIDIR(MAX(B4:B15),B4:B15,0))
La última pregunta la respondemos como la tercera pero ahora se trata de la venta mínima.
En I24 digitamos: =INDICE(A4:A15,COINCIDIR(MIN(B4:B15),B4:B15,0))

Guarde el libro con el nombre "IndiceCoincidir-a.xlsx" y continuemos.

Pasemos a la hoja IndiceCoincidir2.

En esta hoja tenemos las ventas diarias de tres supermercados. Se registran el monto de las ventas de 5 tipos de frutas.

Para no estar seleccionando rangos de frutas, vamos a usar nombre de dichos rangos.
Para ello, seleccione el rango A2:G841.
Use [Fórmulas] - [Nombres definidos] - [Crear desde la selección] . En la ventana de diálogo activar sólo [Fila superior] - [Aceptar]
Ahora, cada columna tiene nombre: Tienda, Dia, etc.
En el lado derecho tenemos tres tablas que debemos completar.
Primera tabla: Debemos usar la función Max(...) para cada fruta. Por ejemplo: En J8: =Max(Manzana). En N8: =Max(Papaya).

Igualmente: En J9 ingresamos: =MIN(Manzana)

Segunda tabla:
En J15 debemos obtener el nombre de la tienda en donde la venta de manzana fue máxima.
Como queremos obtener un dato, debemos usar la función Indice(...).
Y para saber la posición donde la venta de manzana fue máxima, usaremos la función Coincidir(...).
Entonces, en J15 digitamos: =INDICE(Tienda,COINCIDIR(MAX(Manzana),Manzana,0))
En J16 digitamos: =INDICE(Tienda,COINCIDIR(MIN(Manzana),Manzana,0))

En las otras celdas haremos lo mismo, sólo va a cambiar el nombre del rango.

Tercera tabla: Debemos obtener el nombre del día. Para ello usaremos el mismo criterio usado en la tabla anterior, pero en lugar de usar Tienda, usamos Dia.
En J21 digitamos: =INDICE(Dia,COINCIDIR(MAX(Manzana),Manzana,0))
En J22 digitamos: =INDICE(Dia,COINCIDIR(MIN(Manzana),Manzana,0))

Guarde su libro con el mismo nombre (IndiceCoincidir-a.xlsx).

Vaya a la hoja: IndiceCoincidir3.
En esta hoja tenemos del "Número de clientes atendidos por día". Se registra los operdores y el número de clientes atendidos por ellos de Lunes a Viernes.
Debemos responder a cada una de las inquietudes de la parte inferior.

Total de clientes atendidos: En B19 digitamos: =Suma(B4:B15)
Promedio de clientes atendidos: En B20 digitamos: =Promedio(B4:B15). Lo ajustamos a dos decimales.
Máximo número de clientes atendidos: En B21 digitamos: =Max(B4:B15)
Mínimo número de clientes atendidos: En  B22 digitamos: =Min(B4:B15)
Quién atendió más clientes?. Aquí se pide nombre de operador. Puesto que es un dato a ser extraído debemos usar la función Indice y el número de elemento lo dará la función Coincidir.
Entonces, en B23 digitamos: =INDICE($A$4:$A$15,COINCIDIR(MAX(B4:B15),B4:B15,0))
Del mismo modo, en B24 digitamos: =INDICE($A$4:$A$15,COINCIDIR(MIN(B4:B15),B4:B15,0))

Nota:
Hemos usado celdas absolutas en el rango de nombres de operador ya que al copiar a la derecha, las celdas van a cambiar de uno en uno. En nuestro caso deben estar fijas.

Ahora, seleccionamos el rango B19:B24, lo copiamos y seleccionando el rango C19:F24, lo pegamos.

Grabamos el libro con el mismo nombre.

Aqui termina las herramientas y funciones adicionales.

Para pasar a la siguiente sesión haga clic aquí